;******************************************************************************************
;  ＡＶＲサンプル
;   Project      :
;   Program Name : 
;   Programer    :
;   Create date  :  Version 1.0    H23.09.20
;   History      :
;******************************************************************************************
;   Description  :
;    (1)Define I/O PORT
;         PB0: Voltage Reference 2.5V
;         PB1: Voltage Check 
;         PB2: Voltage Control 
;******************************************************************************************
.include "tn13Adef.inc"
.cseg
    LDI   R16,RAMEND
    OUT   SPL,R16

; ********************
; 1.初期化
; ********************
; (1)ポートの初期化
    LDI   R16,0b00000100
    OUT   PORTB,R16 

; (2)コントロールポートを出力に設定
    LDI   R16,(1<<DDB2)|(0<<DDB1)|(0<<DDB0)
    OUT   DDRB,R16 

; (3)コンパレータの初期化
    RCALL Int_CMPR

; ********************
; 2.メイン
; ********************
MAIN:
; (1)ACOフラグをチェックする 
   IN     R16,ACSR 
   SBRC   R16,ACO   
   RJMP   MAIN    

; (2)コントロールポートを動かす（H=>L=>H）
    LDI   R16,0b00000000
    OUT   PORTB,R16 

    RCALL WAT
 
    LDI   R16,0b00000100
    OUT   PORTB,R16 

    RJMP  MAIN

;******************************************************************************************
;   Function Name : Int_CMPR 
;   Title         : コンパレータの初期化
;   Input         :
;   Output        :
;   Description   : 
;******************************************************************************************
Int_CMPR:
    PUSH    R16

; *********************************************************
; 1.ADCSRB(ADC Control and Status Register)
;     ADCSRB[6] ACME  : Analog Comparator Multiplexer Enable
;                    When this bit is written logic one and the ADC is switched off (ADEN in ADCSRA is zero), 
;                    the ADC multiplexer selects the negative input to the Analog Comparator. 
;                    When this bit is written logic zero, AIN1 is applied to the negative input of the Analog
;                    Comparator. 
; *********************************************************
    IN    R16,ADCSRB
    ANDI  R16,0b10111111 
    OUT   ADCSRB,R16

; *********************************************************
; 2.ACSR(Analog Comparator Control and Status Register) 
;      ACSR[7]  ACD:   Analog Comparator Disable
;      ACSR[6]  ACBG:  Analog Comparator Bandgap Select
;      ACSR[5]  ACO:   Analog Comparator Output
;      ACSR[4]  ACI:   Analog Comparator Interrupt Flag
;      ACSR[3]  ACIE:  Analog Comparator Interrupt Enable
;      ACSR[2]  Res:   Reserved Bit
;      ACSR[1]  ACIS1: Analog Comparator Interrupt Mode Select
;      ACSR[0]  ACIS0: Analog Comparator Interrupt Mode Select
; *********************************************************
    LDI   R16,(0<<ACD)|(0<<ACBG)|(0<<ACO)|(0<<ACI)|(0<<ACIE)|(0<<ACIS1)|(0<<ACIS0)    
    OUT   ACSR,R16

; *********************************************************
; 3.DIDR0(Digital Input Disable Register 0)
;      DIDR0[1] AIN1D: AIN1, AIN0 Digital Input Disable
;      DIDR0[0] AIN0D: AIN1, AIN0 Digital Input Disable  
;        When this bit is written logic one, the digital input buffer on the AIN1/0 pin is disabled. 
;        The corresponding PIN Register bit will always read as zero when this bit is set. 
;       When an analog signal is applied to the AIN1/0 pin and the digital input from this pin is not needed, 
;        this bit should be written logic one to reduce power consumption in the digital input buffer.
; *********************************************************
    IN     R16,DIDR0
    ORI    R16,0b00000011
    OUT    DIDR0,R16
                                     
    POP    R16
    RET

;******************************************************************************************
;   Function Name : WAT
;   Title         : タイマー
;   Input         : 
;   Output        : 
;******************************************************************************************
WAT:
;  1.初期化
    PUSH    R16

;  2.タイマー
    LDI     R16,20
WAT_A:	
    NOP
    DEC     R16
    BRNE    WAT_A

;  3.終了処理
    POP     R16

    RET