;******************************************************************************************
;  4桁カウンタサンプル
;    PC/AT電源を使ったタイマー
;   Program Name : 
;   Programer    :
;   Create date  :  Version 1.0    H19.01.10
;   History      :
;******************************************************************************************
;  (0)Display
;     7 Segment Diode ( Anode common type )
;     OSC Inside 8MHz
;  (1)Descript I/O 
;      B0～B7      : 7 Segment diode (a～h) 
;      A0          : PC/AT Power Supply Control(Output)
;      A1          : Push Swtch 1(Input)
;      A2          : Push Swtch 2(Input)
;      A3,A4,A6,A7 : 7 Segment diode (1～4)
;      A5          : None
;******************************************************************************************
	LIST	P=PIC16F88
	INCLUDE	"P16F88.inc"	
	__CONFIG _CONFIG1 , _CP_OFF & _CCP1_RB0 & _DEBUG_OFF & _WRT_PROTECT_OFF & _CPD_OFF & _LVP_OFF & _BODEN_OFF & _MCLR_OFF & _PWRTE_OFF & _WDT_OFF & _INTRC_IO
	__CONFIG _CONFIG2 , _IESO_OFF & _FCMEN_OFF

DN0	EQU	20H
DN1	EQU	21H
DN2	EQU	22H
DN3	EQU	23H
LPDSP	EQU	24H
LPDSP1	EQU	25H
COU0	EQU	26H
COU1	EQU	27H
COU2	EQU	28H
COU3	EQU	29H
CNT1	EQU	2CH
CNT2	EQU	2DH
LP1	EQU	2EH
LP2	EQU	2FH
LPWAT1	EQU	30H
LPWT1B	EQU	31H
PRIOD	EQU	32H

	ORG	0
	GOTO	START
	ORG	4
	GOTO	START
START
; Bank0での設定
	BANKSEL	PORTA	; PortAのBankを選択する
	CLRF	PORTA	; PortAの初期化(Bank0)
	CLRF	PORTB	; PortBの初期化(Bank0,1,2,3)

; Bank1での設定
	BANKSEL	ANSEL	; ANSELのBankを選択する(Bank1)
	MOVLW	B'01111110'	;内部OSC選択,内部OSCに8MHzを選択
	MOVWF	OSCCON
	MOVLW	B'00000000'	;全てのI/OをDegitalに設定
	MOVWF	ANSEL	; Degital Inputに設定(Bank1)
	MOVLW	B'00100110'
	MOVWF	TRISA	; PortAのI/O設定(Bank1)
	MOVLW	B'00000000'
	MOVWF	TRISB	; PortBのI/O設定(Bank1)
	MOVLW	B'10000000'	; 7:10Bitを右詰めで得る,6:?(どっちでも),5-4:ReferはVoltage-GND,3-0:None
	MOVWF	ADCON1	;(Bank1)
; Bank0に戻す
	BANKSEL	PORTA	; PortAのBankを選択する
; デモ表示
MAIN
	CLRF	PRIOD	; 小数点を表示しない
	CALL	DEMO0	; 電源投入時に7-Segment Displayが正常に点灯するか確認する
;	CALL	DEMO1	; デモを表示する
	CALL	SETCOU	; 初期値設定
;
	BSF	PORTA,0	; スイッチをＯＮにする
	BSF	PRIOD,3	; 
MADIN
	CALL	PRGD
	GOTO	MADIN

;******************************************************************************************
;   Function Name : DEC7SEG
;   Title         : DECデコーダと7セグメント表示(アノードコモン用)
;   Input         : W:ワーキングレジスタ
;   Output        : なし
;******************************************************************************************
DEC7SEG
	CALL	TBL7A
	MOVWF	PORTB
	RETURN
TBL7A
	ADDWF	PCL,F
	RETLW	B'10001000'		; 0(00)
	RETLW	B'11111100'		; 1(01)
	RETLW	B'10100010'		; 2(02)
	RETLW	B'11100000'		; 3(03)
	RETLW	B'11010100'		; 4(04)
	RETLW	B'11000001'		; 5(05)
	RETLW	B'10000001'		; 6(06)
	RETLW	B'11111000'		; 7(07)
	RETLW	B'10000000'		; 8(08)
	RETLW	B'11000000'		; 9(09)
	RETLW	B'10010000'		; A(0A)
	RETLW	B'10000101'		; B(0B)
	RETLW	B'10001011'		; C(0C)
	RETLW	B'10100100'		; D(0D)
	RETLW	B'10000011'		; E(0E)
	RETLW	B'10010011'		; F(0F)
	RETLW	B'00000000'		; G(10)
	RETLW	B'00000000'		; H(11)
	RETLW	B'00000000'		; I(12)
	RETLW	B'00000000'		; J(13)
	RETLW	B'00000000'		; K(14)
	RETLW	B'00000000'		; L(15)
	RETLW	B'00000000'		; M(16)
	RETLW	B'00000000'		; N(17)
	RETLW	B'00000000'		; O(18)
	RETLW	B'10010010'		; P(19)
	RETLW	B'00000000'		; Q(1A)
	RETLW	B'10110111'		; R(1B)
	RETLW	B'00000000'		; S(1C)
	RETLW	B'00000000'		; T(1D)
	RETLW	B'10001100'		; U(1E)
	RETLW	B'00000000'		; V(1F)
	RETLW	B'00000000'		; W(20)
	RETLW	B'00000000'		; X(21)
	RETLW	B'00000000'		; Y(22)
	RETLW	B'00000000'		; Z(23)
	RETLW	B'00000000'		; a(24)
	RETLW	B'10000101'		; b(25)
	RETLW	B'10100111'		; c(26)
	RETLW	B'10100100'		; d(27)
	RETLW	B'10000011'		; e(28)
	RETLW	B'10010011'		; f(29)
	RETLW	B'11000000'		; g(2A)
	RETLW	B'00000000'		; h(2B)
	RETLW	B'10111111'		; i(2C)
	RETLW	B'00000000'		; j(2D)
	RETLW	B'00000000'		; k(2E)
	RETLW	B'00000000'		; l(2F)
	RETLW	B'00000000'		; m(30)
	RETLW	B'00000000'		; n(31)
	RETLW	B'00000000'		; o(32)
	RETLW	B'10010010'		; p(33)
	RETLW	B'00000000'		; q(34)
	RETLW	B'10110111'		; r(35)
	RETLW	B'00000000'		; s(36)
	RETLW	B'00000000'		; t(37)
	RETLW	B'00000000'		; u(38)
	RETLW	B'10101101'		; v(39)
	RETLW	B'00000000'		; w(3A)
	RETLW	B'00000000'		; x(3B)
	RETLW	B'00000000'		; y(3C)
	RETLW	B'00000000'		; z(3D)
	RETLW	B'11111111'		;  (3E)
	RETLW	B'00000000'		; -(3F)
	RETLW	B'00000000'		; _(40)
	RETLW	B'00000000'		; 全(41)

;******************************************************************************************
;   Function Name : PRGD
;   Title         : ダウンカウンター
;   Input         : COU0～COU3
;******************************************************************************************
PRGD
; 1.ダウンカウンタ
	CALL	DWCNT
; 2.変数セット
	CALL	SETHEX
; 3.7セグメント表示
	CALL	WATDSP2

	RETURN

;******************************************************************************************
;   Function Name : SETCOU
;   Title         : カウンター初期値を設定
;   Input         : COU0～COU3
;******************************************************************************************
SETCOU
	MOVLW	H'00'
	MOVWF	COU0
	MOVLW	H'00'
	MOVWF	COU1
	MOVLW	H'00'
	MOVWF	COU2
	MOVLW	H'01'
	MOVWF	COU3
	RETURN

;******************************************************************************************
;   Function Name : DWCNT
;   Title         : ダウンカウンタ
;   Input         : COU0,COU1,COU2,COU3
;   Output        : COU0,COU1,COU2,COU3
;******************************************************************************************
DWCNT
	MOVFW	COU0
	XORLW	H'00'
	BTFSC	STATUS,Z
	GOTO	DWCNT2
	DECF	COU0,F
	RETURN
DWCNT2
	MOVLW	H'09'		; 1桁目（１分）は10進カウンタ(0=>9)
	MOVWF	COU0
	MOVFW	COU1
	XORLW	H'00'
	BTFSC	STATUS,Z
	GOTO	DWCNT3
	DECF	COU1,F
	RETURN
DWCNT3
	MOVLW	H'05'		; 2桁目（１０分）は6進カウンタ(0=>5)
	MOVWF	COU1
	MOVFW	COU2
	XORLW	H'00'
	BTFSC	STATUS,Z
	GOTO	DWCNT4
	DECF	COU2,F
	RETURN
DWCNT4
	MOVLW	H'09'		; 3桁目（１時）は10進カウンタ(0=>9)
	MOVWF	COU2
	MOVFW	COU3
	XORLW	H'00'
	BTFSC	STATUS,Z
	GOTO	DWCNT5
	DECF	COU3,F
	RETURN
DWCNT5
;	MOVLW	H'FF'		; 4桁目（１０時）は終了
;	MOVWF	COU0
	CLRF	COU0
	CLRF	COU1
	CLRF	COU2
	CLRF	COU3

	BCF	PORTA,0
	RETURN

;******************************************************************************************
;   Function Name : SETHEX
;   Title         : 16進カウンター変数の７セグメント変数設定
;   Input         : COU0 - COU3
;******************************************************************************************
SETHEX
	MOVFW	COU0
	MOVWF	DN0
	MOVFW	COU1
	MOVWF	DN1
	MOVFW	COU2
	MOVWF	DN2
	MOVFW	COU3
	MOVWF	DN3
	RETURN

;******************************************************************************************
;   Function Name : DEMO0
;   Title         : 7-Segment-LEDの点灯状態確認用関数
;   Input         : なし
;******************************************************************************************
DEMO0
	MOVLW	H'41'
	MOVWF	DN3
	MOVLW	H'41'
	MOVWF	DN2
	MOVLW	H'41'
	MOVWF	DN1
	MOVLW	H'41'
	MOVWF	DN0
	CALL	WATDSP

	RETURN

;******************************************************************************************
;   Function Name : DEMO1
;   Title         : 電源投入時のデモ
;   Input         : なし
;******************************************************************************************
DEMO1
; PicCPU 表示
	MOVLW	H'19'	;P
	MOVWF	DN3
	MOVLW	H'2C'	;i
	MOVWF	DN2
	MOVLW	H'26'	;c
	MOVWF	DN1
	MOVLW	H'3E'	;
	MOVWF	DN0
	CALL	WATDSP

; 16F88 表示
	MOVLW	H'01'	;1
	MOVWF	DN3
	MOVLW	H'06'	;6
	MOVWF	DN2
	MOVLW	H'08'	;8
	MOVWF	DN1
	MOVLW	H'08'	;8
	MOVWF	DN0
	CALL	WATDSP

	RETURN


;******************************************************************************************
;   Function Name : WATDSP
;   Title         : WAITする（1秒程度、7Segmentを表示する）
;   Input         : DN0～DN3
;******************************************************************************************
WATDSP
	MOVLW	H'05'	; 1秒程度点灯
	MOVWF	LPDSP1
WATDP1A
	MOVLW	H'CF'	; 表示時間調整
	MOVWF	LPDSP
WATDSP1
	CALL	C1DSP7
	DECFSZ	LPDSP,F
	GOTO	WATDSP1
	DECFSZ	LPDSP1,F
	GOTO	WATDP1A
	RETURN

;******************************************************************************************
;   Function Name : WATDSP2
;   Title         : 0.05秒程度、7Segmentを表示する
;   Input         : DN0～DN3
;******************************************************************************************
WATDSP2
	MOVLW	H'1B'	; 表示時間調整
	MOVWF	LPDSP
WATDP2A
	CALL	C1DSP7
	DECFSZ	LPDSP,F
	GOTO	WATDP2A
	RETURN

;******************************************************************************************
;   Function Name : C1DSP7
;   Title         : ４桁の数字を設定し、7Segmentを点灯する
;   Input         : DN0～DN5
;   Output        : 
;******************************************************************************************
C1DSP7
;  (0)全ての桁を初期化する
	CALL	DEC7OFF
;  (1)0桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN0
	CALL	DEC7SEG
	BTFSC	PRIOD,0
	BCF	PORTB,7
	BSF	PORTA,3
;    2)Wait
	CALL	WAT1
	BCF	PORTA,3
;  (2)1桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN1
	CALL	DEC7SEG
	BTFSC	PRIOD,1
	BCF	PORTB,7
	BSF	PORTA,4
;    2)Wait
	CALL	WAT1
	BCF	PORTA,4
;  (3)2桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN2
	CALL	DEC7SEG
	BTFSC	PRIOD,2
	BCF	PORTB,7
	BSF	PORTA,6
;    2)Wait
	CALL	WAT1
	BCF	PORTA,6
;  (4)3桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN3
	CALL	DEC7SEG
	BTFSC	PRIOD,3
	BCF	PORTB,7
	BSF	PORTA,7
;    2)Wait
	CALL	WAT1
	BCF	PORTA,7

	RETURN

;******************************************************************************************
;   Function Name : DEC7OFF
;   Title         : 7セグメント表示の全桁を初期化
;   Input         : 
;   Output        : 
;******************************************************************************************
DEC7OFF
	BCF	PORTA,3
	BCF	PORTA,4
	BCF	PORTA,6
	BCF	PORTA,7
	RETURN

;******************************************************************************************
;   Function Name : WAT1
;   Title         : タイマー関数(7 Segment表示機の桁間WAIT)
;   Input         : 
;   Output        : 
;******************************************************************************************
WAT1
	MOVLW	H'FF'
	MOVWF	LPWT1B
WAT1B
	MOVLW	H'FF'
	MOVWF	LPWAT1
WAT1A
	DECFSZ	LPWAT1,F
	GOTO	WAT1A
;	DECFSZ	LPWT1B,F
;	GOTO	WAT1B

	RETURN

	END
