;******************************************************************************************
;  電圧計サンプル
;   Program Name : 
;   Programer    :
;   Create date  :  Version 1.0    H17.07.09
;   History      :
;******************************************************************************************
;  (0)Display
;     7 Segment Diode ( Anode common type )
;     内部オシレータを使用する
;  (1)Descript I/O 
;      B0～B6 : 7 Segment diode (a～g) 
;      B7,A1  : ADC Input (Analog Input)
;      A0,A2～A4,A6,A7 : 7 Segment diode (1～6)
;      A5     : Input Mode Selecter switch 
;******************************************************************************************
	LIST	P=PIC16F88
	INCLUDE	"P16F88.inc"	
	__CONFIG _CONFIG1 , _CP_OFF & _CCP1_RB0 & _DEBUG_OFF & _WRT_PROTECT_OFF & _CPD_OFF & _LVP_OFF & _BODEN_OFF & _MCLR_OFF & _PWRTE_OFF & _WDT_OFF & _INTRC_IO
	__CONFIG _CONFIG2 , _IESO_OFF & _FCMEN_OFF

DN0	EQU	20H
DN1	EQU	21H
DN2	EQU	22H
DN3	EQU	23H
DN4	EQU	24H
DN5	EQU	25H
LPWAT1	EQU	26H
LPWT1B	EQU	27H
LPWAT2	EQU	28H
LPWT2B	EQU	29H
LPWT2C	EQU	2AH
LPDSP	EQU	2BH
LPDSP1	EQU	2CH
LDEM1A	EQU	2DH
COU0	EQU	2EH
COU1	EQU	2FH
COU2	EQU	30H
COU3	EQU	31H
COU4	EQU	32H
COU5	EQU	33H
DECCOU0	EQU	34H
DECCOU1	EQU	35H
DECCOU2	EQU	36H
DECCOU3	EQU	37H
DECCOU4	EQU	38H
DECCOU5	EQU	39H
ADANSL	EQU	3AH
ADANSR	EQU	3BH
CNT1	EQU	3CH
CNT2	EQU	3DH
LP1	EQU	3EH
LP2	EQU	3FH

	ORG	0
	GOTO	START
	ORG	4
	GOTO	START
START
; Bank0での設定
	BANKSEL	PORTA	; PortAのBankを選択する(Bank0 ※PortBは0,2,3にあるので指定注意)
	CLRF	PORTA	; PortAの初期化(Bank0)
	CLRF	PORTB	; PortBの初期化(Bank0,1,2,3)

; Bank1での設定
	BANKSEL	ANSEL	; ANSELのBankを選択する(Bank1)
	MOVLW	B'01111110'	;内部OSC選択,内部OSCに4MHzを選択
	MOVWF	OSCCON
	MOVLW	B'01000010'	;AN6(RB7),AN1(RA1)をAnalog-Input, 他をDegitalに設定
	MOVWF	ANSEL	; Degital Inputに設定(Bank1)
	MOVLW	B'00100010'
	MOVWF	TRISA	; PortAのI/O設定(Bank1)
	MOVLW	B'10000000'
	MOVWF	TRISB	; PortBのI/O設定(Bank1)
	MOVLW	B'10000000'	; 7:10Bitを右詰めで得る,6:?(どっちでも),5-4:ReferはVoltage-GND,3-0:None
	MOVWF	ADCON1	;(Bank1)
; Bank0に戻す
	BANKSEL	PORTA	; PortAのBankを選択する(Bank0 ※PortBは0,2,3にあるので指定注意)

; デモ表示
MAIN
	CALL	DEMO0	; 電源投入時に7-Segment Displayが正常に点灯するか確認する(約5秒)
	CALL	DEMO1	; デモを表示する(約10秒)
;(1)電圧計モード
MADIN
	CALL	DSPA
	CALL	DSPB
	GOTO	MADIN

;******************************************************************************************
;   Function Name : DEC7SEG
;   Disctiption   : DECデコーダと7セグメント表示
;   Input         : W:ワーキングレジスタ
;   Output        : なし
;******************************************************************************************
DEC7SEG
	CALL	TBL7A
	MOVWF	PORTB
	RETURN
TBL7A
	ADDWF	PCL,F
	RETLW	B'00001000'		; 0(00)
	RETLW	B'01111100'		; 1(01)
	RETLW	B'00100010'		; 2(02)
	RETLW	B'01100000'		; 3(03)
	RETLW	B'01010100'		; 4(04)
	RETLW	B'01000001'		; 5(05)
	RETLW	B'00000001'		; 6(06)
	RETLW	B'01111000'		; 7(07)
	RETLW	B'00000000'		; 8(08)
	RETLW	B'01000000'		; 9(09)
	RETLW	B'00010000'		; A(0A)
	RETLW	B'00000101'		; B(0B)
	RETLW	B'00001011'		; C(0C)
	RETLW	B'00100100'		; D(0D)
	RETLW	B'00000011'		; E(0E)
	RETLW	B'00010011'		; F(0F)
	RETLW	B'00000000'		; G(10)
	RETLW	B'00000000'		; H(11)
	RETLW	B'00000000'		; I(12)
	RETLW	B'00000000'		; J(13)
	RETLW	B'00000000'		; K(14)
	RETLW	B'00000000'		; L(15)
	RETLW	B'00000000'		; M(16)
	RETLW	B'00000000'		; N(17)
	RETLW	B'00000000'		; O(18)
	RETLW	B'00010010'		; P(19)
	RETLW	B'00000000'		; Q(1A)
	RETLW	B'00110111'		; R(1B)
	RETLW	B'00000000'		; S(1C)
	RETLW	B'00000000'		; T(1D)
	RETLW	B'00001100'		; U(1E)
	RETLW	B'00000000'		; V(1F)
	RETLW	B'00000000'		; W(20)
	RETLW	B'00000000'		; X(21)
	RETLW	B'00000000'		; Y(22)
	RETLW	B'00000000'		; Z(23)
	RETLW	B'00000000'		; a(24)
	RETLW	B'00000101'		; b(25)
	RETLW	B'00100111'		; c(26)
	RETLW	B'00100100'		; d(27)
	RETLW	B'00000011'		; e(28)
	RETLW	B'00010011'		; f(29)
	RETLW	B'01000000'		; g(2A)
	RETLW	B'00000000'		; h(2B)
	RETLW	B'00111111'		; i(2C)
	RETLW	B'00000000'		; j(2D)
	RETLW	B'00000000'		; k(2E)
	RETLW	B'00000000'		; l(2F)
	RETLW	B'00000000'		; m(30)
	RETLW	B'00000000'		; n(31)
	RETLW	B'00000000'		; o(32)
	RETLW	B'00010010'		; p(33)
	RETLW	B'00000000'		; q(34)
	RETLW	B'00110111'		; r(35)
	RETLW	B'00000000'		; s(36)
	RETLW	B'00000000'		; t(37)
	RETLW	B'00000000'		; u(38)
	RETLW	B'00101101'		; v(39)
	RETLW	B'00000000'		; w(3A)
	RETLW	B'00000000'		; x(3B)
	RETLW	B'00000000'		; y(3C)
	RETLW	B'00000000'		; z(3D)
	RETLW	B'01111111'		;  (3E)
	RETLW	B'00000000'		; -(3F)
	RETLW	B'00000000'		; _(40)

;******************************************************************************************
;   Function Name : DSPA
;   Disctiption   : Ａ端子の電圧を表示する
;   Input         : なし
;******************************************************************************************
DSPA
;    (1)A端子の電圧を得る
	CALL	GETVA
	CALL	GETVA

;    (2)10Bit-A/D-Converterの出力を4桁10進数に変換する
	CALL	HEXDEC

;    (3)7-Segment表示用変数に表示内容を設定する
	MOVLW	H'0A'	;A
	MOVWF	DN5
	MOVLW	H'3E'	;(Space)
	MOVWF	DN4
	MOVFW	DECCOU2	;n
	MOVWF	DN3
	MOVFW	DECCOU1	;n
	MOVWF	DN2
	MOVFW	DECCOU0	;n
	MOVWF	DN1
	MOVLW	H'39'	;v
	MOVWF	DN0

;    (4)7-Segment-Displayを約3秒表示する
	CALL	WATDSP3

	RETURN

;******************************************************************************************
;   Function Name : DSPB
;   Disctiption   : Ｂ端子の電圧を表示する
;   Input         : なし
;******************************************************************************************
DSPB
;    (1)B端子の電圧を得る
	CALL	GETVB
	CALL	GETVB

;    (2)10Bit-A/D-Converterの出力を4桁10進数に変換する
	CALL	HEXDEC

;    (3)7-Segment表示用変数に表示内容を設定する
	MOVLW	H'0B'	;B
	MOVWF	DN5
	MOVLW	H'3E'	;(Space)
	MOVWF	DN4
	MOVFW	DECCOU2	;n
	MOVWF	DN3
	MOVFW	DECCOU1	;n
	MOVWF	DN2
	MOVFW	DECCOU0	;n
	MOVWF	DN1
	MOVLW	H'39'	;v
	MOVWF	DN0

;    (4)7-Segment-Displayを約3秒表示する
	CALL	WATDSP3

	RETURN

;******************************************************************************************
;   Function Name : GETVA
;   Disctiption   : Ａ端子の電圧を得る
;   Input         : なし
;   Output        : ADANSL,ADANSR
;******************************************************************************************
GETVA
	BANKSEL	PORTA	; BANK0を選択する
; ADCON0[7:6]  サンプリング周波数；Fosc/32(OSC周波数の1/32:最も遅い設定)
; ADCON0[5-3]  Chanel-1(AN1)を選択
; ADCON0[2]    Go/Done
; ADCON0[1]    None
; ADCON0[0]    A/D-Converter ON
	MOVLW	B'10001101'	
	MOVWF	ADCON0	;(Bank0)
GETVA1
	BTFSC	ADCON0,2; ADCの開始フラグが完了するまで待つ
	GOTO	GETVA1	; ADCの開始フラグが完了するまで待つ
	MOVFW	ADRESH	; 上位２ビットデータ収集(Bank0)
	MOVWF	ADANSL	; 上位２ビットデータ代入
	BANKSEL	ANSEL	; Bank1を選択する
	MOVFW	ADRESL	; 下位８ビットデータ収集(Bank1)
	BANKSEL	PORTA	; BANK0を選択する
	MOVWF	ADANSR	; 下位８ビットデータ代入

	RETURN

;******************************************************************************************
;   Function Name : GETVB
;   Disctiption   : Ｂ端子の電圧を得る
;   Input         : なし
;   Output        : ADANSL,ADANSR
;******************************************************************************************
GETVB
	BANKSEL	PORTA	; BANK0を選択する
; ADCON0[7:6]  サンプリング周波数；Fosc/32(OSC周波数の1/32:最も遅い設定)
; ADCON0[5-3]  Chanel-6(AN6)を選択
; ADCON0[2]    Go/Done
; ADCON0[1]    None
; ADCON0[0]    A/D-Converter ON
	MOVLW	B'10110101'	
	MOVWF	ADCON0	;(Bank0)
GETVB1
	BTFSC	ADCON0,2; ADCの開始フラグが完了するまで待つ
	GOTO	GETVB1	; ADCの開始フラグが完了するまで待つ
	MOVFW	ADRESH	; 上位２ビットデータ収集(Bank0)
	MOVWF	ADANSL	; 上位２ビットデータ代入
	BANKSEL	ANSEL	; Bank1を選択する
	MOVFW	ADRESL	; 下位８ビットデータ収集(Bank1)
	BANKSEL	PORTA	; BANK0を選択する
	MOVWF	ADANSR	; 下位８ビットデータ代入

	RETURN

;******************************************************************************************
;   Function Name : DEMO0
;   Disctiption   : 7-Segment-LEDの点灯状態確認用関数(約5秒)
;   Input         : なし
;******************************************************************************************
DEMO0
; 888888 表示	
	MOVLW	H'08'	;8
	MOVWF	DN5
	MOVLW	H'08'	;8
	MOVWF	DN4
	MOVLW	H'08'	;8
	MOVWF	DN3
	MOVLW	H'08'	;8
	MOVWF	DN2
	MOVLW	H'08'	;8
	MOVWF	DN1
	MOVLW	H'08'	;8
	MOVWF	DN0
	CALL	WATDSP

	RETURN

;******************************************************************************************
;   Function Name : DEMO1
;   Disctiption   : 電源投入時のデモ(約10秒)
;   Input         : なし
;******************************************************************************************
DEMO1
; PicCPU 表示
	MOVLW	H'19'	;P
	MOVWF	DN5
	MOVLW	H'2C'	;i
	MOVWF	DN4
	MOVLW	H'26'	;c
	MOVWF	DN3
	MOVLW	H'0C'	;C
	MOVWF	DN2
	MOVLW	H'19'	;P
	MOVWF	DN1
	MOVLW	H'1E'	;U
	MOVWF	DN0
	CALL	WATDSP

; 16F88 表示
	MOVLW	H'3E'	; 
	MOVWF	DN5
	MOVLW	H'01'	;1
	MOVWF	DN4
	MOVLW	H'06'	;6
	MOVWF	DN3
	MOVLW	H'0F'	;F
	MOVWF	DN2
	MOVLW	H'08'	;8
	MOVWF	DN1
	MOVLW	H'08'	;8
	MOVWF	DN0
	CALL	WATDSP

	RETURN

;******************************************************************************************
;   Function Name : SETDEC
;   Disctiption   : 10進カウンター変数の７セグメント変数設定
;   Input         : COU0 - COU5
;******************************************************************************************
SETDEC
	MOVFW	DECCOU0
	MOVWF	DN0
	MOVFW	DECCOU1
	MOVWF	DN1
	MOVFW	DECCOU2
	MOVWF	DN2
	MOVFW	DECCOU3
	MOVWF	DN3
	MOVFW	DECCOU4
	MOVWF	DN4
	MOVFW	DECCOU5
	MOVWF	DN5

	RETURN

;******************************************************************************************
;   Function Name : SETHEX
;   Disctiption   : 16進カウンター変数の７セグメント変数設定
;   Input         : COU0 - COU5
;******************************************************************************************
SETHEX
	MOVFW	COU0
	MOVWF	DN0
	MOVFW	COU1
	MOVWF	DN1
	MOVFW	COU2
	MOVWF	DN2
	MOVFW	COU3
	MOVWF	DN3
	MOVFW	COU4
	MOVWF	DN4
	MOVFW	COU5
	MOVWF	DN5

	RETURN
;******************************************************************************************
;   Function Name : HEXCOU
;   Disctiption   : 16進(6桁)アップカウンター
;   Input         : COU0～COU5
;******************************************************************************************
HEXCOU
; 0桁目
	MOVLW	H'01'
	ADDWF	COU0,F
	BTFSS	COU0,4	 	
	RETURN
; 1桁目
	MOVFW	COU0
	ANDLW	B'00001111'	
	MOVWF	COU0
	MOVLW	H'01'
	ADDWF	COU1,F
	BTFSS	COU1,4	 
	RETURN	
; 2桁目
	MOVFW	COU1
	ANDLW	B'00001111'	
	MOVWF	COU1
	MOVLW	H'01'
	ADDWF	COU2,F
	BTFSS	COU2,4	 
	RETURN	
; 3桁目
	MOVFW	COU2
	ANDLW	B'00001111'	
	MOVWF	COU2
	MOVLW	H'01'
	ADDWF	COU3,F
	BTFSS	COU3,4	 
	RETURN		
; 4桁目
	MOVFW	COU3
	ANDLW	B'00001111'	
	MOVWF	COU3
	MOVLW	H'01'
	ADDWF	COU4,F
	BTFSS	COU4,4	 
	RETURN	
; 5桁目
	MOVFW	COU4
	ANDLW	B'00001111'	
	MOVWF	COU4
	MOVLW	H'01'
	ADDWF	COU5,F
	BTFSS	COU5,4	 
	RETURN	
; 桁上がり
	CLRF	COU0
	CLRF	COU1
	CLRF	COU2
	CLRF	COU3
	CLRF	COU4
	CLRF	COU5
	RETURN	

;******************************************************************************************
;   Function Name : HEXDEC
;   Disctiption   : 10Bit-A/D-Converter の16進数を文字型10進数(4桁)に変換する
;   Input         : ADANSL,ADANSR (10Bit-A/D-Converterの出力形式)
;   Output        : DECCOU0,DECCOU1,DECCOU2,DECCOU3(4桁の10進数)
;******************************************************************************************

HEXDEC
; (1)10進数の出力変数を初期化　
	CLRF	DECCOU0
	CLRF	DECCOU1
	CLRF	DECCOU2
	CLRF	DECCOU3
	CLRF	DECCOU4
	CLRF	DECCOU5
;
; (2)16進数を10進数に変換する
;   ※ Binary-16進数の値分だけ10進カウンタを回して、Binary-16進数を文字型10進数の
;      DECCOU0,DECCOU1,DECCOU2,DECCOU3にカウントアップして10進数を作り出す
;
	MOVFW	ADANSL
	XORLW	H'00'
	BTFSC	STATUS,Z
	GOTO	HEXDEE
;
	MOVFW	ADANSL
	MOVWF	CNT2
HEXDEC2
	MOVLW	H'FF'
	MOVWF	CNT1
	CALL	CNTDEC
HEXDEC1
	CALL	CNTDEC
	DECFSZ	CNT1,F
	GOTO	HEXDEC1 
	DECFSZ	CNT2,F
	GOTO	HEXDEC2
;
HEXDEE
	MOVFW	ADANSR
	XORLW	H'00'
	BTFSC	STATUS,Z
	GOTO	HEXDECE

	MOVFW	ADANSR
	MOVWF	CNT1
HEXDEE1
	CALL	CNTDEC
	DECFSZ	CNT1,F
	GOTO	HEXDEE1 
HEXDECE
	RETURN

;******************************************************************************************
;   Function Name : CNTDEC(HEXDEC関数からも使用しているので仕様変更はするな！)
;   Disctiption   : 10進(6桁)アップカウンタ
;   Input         : DECCOU0,DECCOU1,DECCOU2,DECCOU3,DECCOU4,DECCOU5
;   Output        : DECCOU0,DECCOU1,DECCOU2,DECCOU3,DECCOU4,DECCOU5
;******************************************************************************************
CNTDEC
	MOVLW	H'01'
	ADDWF	DECCOU0,F	; 0桁目10進カウンタ(0aで桁上げ)
	MOVFW	DECCOU0
	XORLW	H'0A'
	BTFSS	STATUS,Z
	RETURN
;
	CLRF	DECCOU0
	MOVLW	H'01'
	ADDWF	DECCOU1,F	; 1桁目10進カウンタ(0aで桁上げ)
	MOVFW	DECCOU1
	XORLW	H'0A'
	BTFSS	STATUS,Z
	RETURN
;
	CLRF	DECCOU1
	MOVLW	H'01'
	ADDWF	DECCOU2,F	; 2桁目10進カウンタ(0aで桁上げ)
	MOVFW	DECCOU2
	XORLW	H'0A'
	BTFSS	STATUS,Z
	RETURN
;
	CLRF	DECCOU2
	MOVLW	H'01'
	ADDWF	DECCOU3,F	; 3桁目10進カウンタ(0aで桁上げ)
	MOVFW	DECCOU3
	XORLW	H'0A'
	BTFSS	STATUS,Z
	RETURN
;
	CLRF	DECCOU3
	MOVLW	H'01'
	ADDWF	DECCOU4,F	; 4桁目10進カウンタ(0aで桁上げ)
	MOVFW	DECCOU4
	XORLW	H'0A'
	BTFSS	STATUS,Z
	RETURN
;
	CLRF	DECCOU4
	MOVLW	H'01'
	ADDWF	DECCOU5,F	; 5桁目10進カウンタ(0aで桁上げ)
	MOVFW	DECCOU5
	XORLW	H'0A'
	BTFSS	STATUS,Z
	RETURN
;
	CLRF	DECCOU0
	CLRF	DECCOU1
	CLRF	DECCOU2
	CLRF	DECCOU3
	CLRF	DECCOU4
	CLRF	DECCOU5
;
	RETURN

;******************************************************************************************
;   Function Name : WATDSP3
;   Disctiption   : WAITする（3秒程度、7Segmentを表示する）
;   Input         : DN0～DN5
;******************************************************************************************
WATDSP3
	MOVLW	H'05'	; 3秒程度点灯
	MOVWF	LPDSP1
WATDP3A
	MOVLW	H'CF'	; 表示時間調整
	MOVWF	LPDSP
WATDP3
	CALL	C1DSP7
	DECFSZ	LPDSP,F
	GOTO	WATDP3
	DECFSZ	LPDSP1,F
	GOTO	WATDP3A
	RETURN

;******************************************************************************************
;   Function Name : WATDSP2
;   Disctiption   : 0.05秒程度、7Segmentを表示する
;   Input         : DN0～DN5
;******************************************************************************************
WATDSP2
	MOVLW	H'1B'	; 表示時間調整
	MOVWF	LPDSP
WATDP2A
	CALL	C1DSP7
	DECFSZ	LPDSP,F
	GOTO	WATDP2A
	RETURN

;******************************************************************************************
;   Function Name : WATDSP
;   Disctiption   : WAITする（5秒程度、7Segmentを表示する）
;   Input         : DN0～DN5
;******************************************************************************************
WATDSP
	MOVLW	H'0A'	; 5秒程度点灯
	MOVWF	LPDSP1
WATDP1A
	MOVLW	H'CF'	; 表示時間調整
	MOVWF	LPDSP
WATDSP1
	CALL	C1DSP7
	DECFSZ	LPDSP,F
	GOTO	WATDSP1
	DECFSZ	LPDSP1,F
	GOTO	WATDP1A
	RETURN

;******************************************************************************************
;   Function Name : C1DSP7
;   Disctiption   : ６桁の数字を設定し、7Segmentを点灯する
;   Input         : DN0～DN5
;   Output        : 
;******************************************************************************************
C1DSP7
;  (0)全ての桁を初期化する
	CALL	DEC7OFF
;  (1)0桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN0
	CALL	DEC7SEG
	BSF	PORTA,0
;    2)Wait
	CALL	WAT1
	BCF	PORTA,0
;  (2)1桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN1
	CALL	DEC7SEG
	BSF	PORTA,2
;    2)Wait
	CALL	WAT1
	BCF	PORTA,2
;  (3)2桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN2
	CALL	DEC7SEG
	BSF	PORTA,3
;    2)Wait
	CALL	WAT1
	BCF	PORTA,3
;  (4)3桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN3
	CALL	DEC7SEG
	BSF	PORTA,4
;    2)Wait
	CALL	WAT1
	BCF	PORTA,4
;  (5)4桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN4
	CALL	DEC7SEG
	BSF	PORTA,6
;    2)Wait
	CALL	WAT1
	BCF	PORTA,6
;  (6)5桁目の処理
;    1)数字をドットパターンに変換して表示する
	MOVFW	DN5
	CALL	DEC7SEG
	BSF	PORTA,7
;    2)Wait
	CALL	WAT1
	BCF	PORTA,7

	RETURN

;******************************************************************************************
;   Function Name : DEC7OFF
;   Disctiption   : 7セグメント表示の全桁を初期化
;		　　　A0,A2～A4,A6,A7をゼロにする(7 Segment diode の1～6)
;   Input         : 
;   Output        : 
;******************************************************************************************
DEC7OFF
	BCF	PORTA,0
	BCF	PORTA,2
	BCF	PORTA,3
	BCF	PORTA,4
	BCF	PORTA,6
	BCF	PORTA,7
	RETURN

;******************************************************************************************
;   Function Name : WAT1
;   Disctiption   : タイマー関数(7 Segment表示機の桁間WAIT)
;   Input         : 
;   Output        : 
;******************************************************************************************
WAT1
	MOVLW	H'FF'
	MOVWF	LPWT1B
WAT1B
	MOVLW	H'FF'
	MOVWF	LPWAT1
WAT1A
	DECFSZ	LPWAT1,F
	GOTO	WAT1A
;	DECFSZ	LPWT1B,F
;	GOTO	WAT1B

	RETURN

;******************************************************************************************
;   Function Name : WAT2
;   Disctiption   : タイマー関数(7 Segment表示機の文字表示間隔時間)
;   Input         : 
;   Output        : 
;******************************************************************************************
WAT2
	MOVLW	H'FF'
	MOVWF	LPWT2B
WAT2B
	MOVLW	H'FF'
	MOVWF	LPWAT2
WAT2A
	DECFSZ	LPWAT2,F
	GOTO	WAT2A
	DECFSZ	LPWT2B,F
	GOTO	WAT2B

	RETURN

	END
